Percent Change Formula in Excel (With Examples)
· 7 min read
The percent change formula is the new value minus the old value, divided by the old value. Format the result as a percentage. A positive result is an increase, a negative one is a decrease.
=(new - old) / oldIf last month is in C2 and this month is in D2, that is =(D2-C2)/C2. An equivalent, shorter form is =D2/C2-1. Both give exactly the same result.
Worked example: month on month by product
Revenue for four products in September and October:
| A | B | C | D | E | F | G | H | |
|---|---|---|---|---|---|---|---|---|
| 1 | Product | Category | September | October | Change | Variation (copy paper) | Result | |
| 2 | Copy paper | Office | 12,400 | 13,640 | 10.0% | Short form | 10.0% | |
| 3 | Coffee pods | Kitchen | 8,000 | 7,400 | -7.5% | No brackets (wrong) | 13,639 | |
| 4 | Glass cleaner | Cleaning | 2,500 | 3,250 | 30.0% | September plus 10% | 13,640 | |
| 5 | Sticky notes | Office | 1,600 | 1,600 | 0.0% | October back to September | 12,400 | |
| 6 | October minus 10% | 12,276 |
E2 holds =(D2-C2)/C2, filled down to E5. Check the first row by hand: 13,640 minus 12,400 is 1,240, and 1,240 divided by 12,400 is 0.10, which the percent format shows as 10.0%.
Coffee pods fell by 600, and 600 / 8,000 = 0.075, so the result is -7.5%.
The brackets are not optional
Excel divides before it subtracts. =D2-C2/C2 calculates C2/C2 first (which is 1) and then takes it away from D2. For copy paper that gives 13,639 (H3 in the sheet above), which is obviously not a percentage, but in a long column it is easy to miss. Always wrap the subtraction in brackets, or use the =D2/C2-1 form.
Percentage increase formula
The percentage increase formula is the same percent change formula. The word "increase" just tells you the result should be positive. If it comes out negative, it was a decrease.
The reverse question also comes up: "what is 12,400 increased by 10%?"
=C2*(1+10%)Result: 13,640. And to go back from the new value to the old one: =13640/(1+10%) returns 12,400. Note that dividing by 1.1 is not the same as subtracting 10%. Taking 10% off 13,640 gives 12,276. H4 to H6 in the sheet above show all three.
Month over month change
For a time series, each row is compared with the row above. Here is one category's revenue by month:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Month | Orders | Revenue | MoM change |
| 2 | Jan | 160 | 20,000 | n/a |
| 3 | Feb | 151 | 18,500 | -7.5% |
| 4 | Mar | 178 | 22,200 | 20.0% |
| 5 | Apr | 175 | 22,200 | 0.0% |
| 6 | ||||
| 7 | Mar vs Jan | 11.0% | ||
| 8 | Avg of MoM | 4.2% |
The first formula goes in D3, not D2, because January has no previous month to compare with:
=(C3-C2)/C2Fill it down to D5. Leave D2 empty, or write "n/a". Do not put a zero there: a 0% change in January is a claim the data does not support.
Notice that March is up 20% on February but only 11% on January (D7). Percent changes do not add up across periods. A 7.5% fall followed by a 20% rise is a net change of 11% from January, not 12.5%.
Excel formula for percentage difference
"Percent change" and "percentage difference" are often used as the same thing, but strictly they are different:
- Percent change has a direction. There is an old value and a new value, like last month and this month.
- Percentage difference compares two values with no "before" or "after", like two suppliers' prices. It divides by the average of the two.
=ABS(A2-B2)/AVERAGE(A2,B2)For prices of 40 and 50: the difference is 10, the average is 45, so the percentage difference is 22.2%. Compare that with percent change, which depends on direction: from 40 to 50 is +25%, from 50 to 40 is -20%.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Supplier 1 | Supplier 2 | % difference | Change 1 to 2 | Change 2 to 1 |
| 2 | 40 | 50 | 22.2% | 25.0% | -20.0% |
If your manager asks "what is the percentage difference", ask which they mean.
Zero and negative starting values
Old value is zero. A product that sold nothing in September and 500 in October has no meaningful percent change. The formula returns #DIV/0!. Handle it explicitly:
=IF(C2=0, "new", (D2-C2)/C2)You can use IFERROR here too, but an IF that tests the actual reason is clearer. Our IFERROR guide explains when each is the better fit.
Old value is negative. Profit going from -2,000 to 1,000 is an improvement, but =(1000-(-2000))/-2000 returns -150%, which reads like a fall. A common fix is to divide by the absolute value of the old number:
=(D2-C2)/ABS(C2)That returns +150%. Many analysts prefer to show the change in currency instead and skip the percentage, which avoids the confusion completely.
Both cases side by side, with the plain formula next to the fixed one:
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Line | Category | September | October | Plain change | Fixed |
| 2 | Descaler | Kitchen | 0 | 500 | #DIV/0! | new |
| 3 | Profit | All | -2,000 | 1,000 | -150% | 150% |
Percent change vs percentage points
If a margin goes from 20% to 25%, it rose by 5 percentage points. The percent change is (25% - 20%) / 20% = 25%. Both are correct, and they mean very different things. When you compare two percentages, say which one you are reporting.
Common mistakes
Dividing by the new value. This is the mistake AI assistants make most with growth numbers. =(D2-C2)/D2 looks right at a glance and gives sensible-looking results. For copy paper it returns 9.1% instead of 10%. The fix is to check one row by hand: the denominator must be the "before" value. A quick sanity test: if a value doubles, the change must be exactly 100%. Dividing by the new value gives 50%.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Product | Category | September | October | AI's formula | Fixed |
| 2 | Copy paper | Office | 12,400 | 13,640 | 9.1% | 10.0% |
| 3 | Coffee pods | Kitchen | 8,000 | 7,400 | -8.1% | -7.5% |
| 4 | Glass cleaner | Cleaning | 2,500 | 3,250 | 23.1% | 30.0% |
| 5 | Sticky notes | Office | 1,600 | 1,600 | 0.0% | 0.0% |
| 6 | Doubling test | Test | 1,000 | 2,000 | 50.0% | 100.0% |
Comparing the wrong periods. In a sheet with several quarter or month columns, an AI may reference the wrong pair, such as Q1 against Q3 when you asked for Q3 against Q2. Click the cell and read the references in the formula bar.
Multiplying by 100 and then formatting as %. That turns 10% into 1000%. Use one or the other.
Starting the series in the first row. A MoM formula in row 2 refers to the header in row 1 and returns #VALUE!, or worse, compares with a row of a different item.
Averaging percent changes. The average of -7.5%, 20% and 0% is 4.2% (D8 in the month sheet), but that is not the average monthly growth. For growth over several periods, compare the end with the start.
FAQ
What is the formula for percent change in Excel?
=(new-old)/old, for example =(D2-C2)/C2, formatted as a percentage. =D2/C2-1 gives the same result.
How do I calculate percentage increase between two numbers?
Use the same formula. Subtract the old number from the new one and divide by the old one. A positive result is an increase.
How do I calculate month over month change in Excel?
Put the formula in the second month's row and compare it with the row above: =(C3-C2)/C2. Fill it down. The first month has no change to show.
What is the difference between percent change and percentage difference?
Percent change has a starting point and divides by the old value. Percentage difference compares two values as equals and divides by their average.
Why does my percent change show #DIV/0!?
The old value is zero or empty. Decide what the report should show in that case and test for it with IF. See also percentage of total in Excel for the related share-of-total formula.
Practise this on a realistic dataset
Solve it yourself on one company's data, with instant feedback that points at what's wrong without giving away the answer.
Try “West: month-over-month change” →